mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-09-02 01:35:32 +00:00
ecf08f0621
dc4e6b1329
; Update copyright years in more files64b3777631
; Run set-copyright from admin.el8e1c56ae46
; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
150 lines
4.8 KiB
EmacsLisp
150 lines
4.8 KiB
EmacsLisp
;;; erc-sound.el --- CTCP SOUND support for ERC -*- lexical-binding: t -*-
|
|
|
|
;; Copyright (C) 2002-2003, 2006-2024 Free Software Foundation, Inc.
|
|
|
|
;; Maintainer: Amin Bandali <bandali@gnu.org>, F. Jason Park <jp@neverwas.me>
|
|
;; URL: https://www.emacswiki.org/emacs/ErcSound
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Play sounds when users send you CTCP SOUND messages.
|
|
|
|
;; This file also defines the command /sound so that you can send
|
|
;; sound requests to other users.
|
|
|
|
;;; Usage:
|
|
|
|
;; Add the following to your .emacs if you want to play sounds.
|
|
;;
|
|
;; (require 'erc-sound)
|
|
;; (erc-sound-enable)
|
|
;;
|
|
;; To send requests to other users from within query buffers, type the
|
|
;; following:
|
|
;;
|
|
;; /sound filename optional-message-text
|
|
;;
|
|
;; You can also type the following:
|
|
;;
|
|
;; /ctcp nickname sound filename optional-message
|
|
|
|
;;; Code:
|
|
|
|
(require 'erc)
|
|
|
|
(defgroup erc-sound nil
|
|
"Make ERC play bells and whistles while chatting with people."
|
|
:group 'erc)
|
|
|
|
;;;###autoload(put 'ctcp-sound 'erc--module 'sound)
|
|
;;;###autoload(autoload 'erc-sound-mode "erc-sound")
|
|
(define-erc-module sound ctcp-sound
|
|
"In ERC sound mode, the client will respond to CTCP SOUND requests
|
|
and play sound files as requested."
|
|
;; Enable:
|
|
((add-hook 'erc-ctcp-query-SOUND-hook #'erc-ctcp-query-SOUND)
|
|
(define-key erc-mode-map "\C-c\C-s" #'erc-toggle-sound))
|
|
;; Disable:
|
|
((remove-hook 'erc-ctcp-query-SOUND-hook #'erc-ctcp-query-SOUND)
|
|
(define-key erc-mode-map "\C-c\C-s" #'undefined)))
|
|
|
|
(defvar erc-message-english-CTCP-SOUND "%n (%u@%h) plays %s:%m"
|
|
"English template for a CTCP SOUND message.")
|
|
|
|
(defcustom erc-play-sound t
|
|
"Play sounds when you receive CTCP SOUND requests."
|
|
:type 'boolean)
|
|
|
|
(defcustom erc-sound-path nil
|
|
"List of directories that contain sound samples to play on SOUND events."
|
|
:type '(repeat directory))
|
|
|
|
(defcustom erc-default-sound nil
|
|
"Play this sound if the requested file was not found.
|
|
If this is set to nil or the file doesn't exist a beep will sound."
|
|
:type '(choice (const nil)
|
|
file))
|
|
|
|
(defvar erc-ctcp-query-SOUND-hook nil
|
|
"Hook to run after receiving a CTCP SOUND request.")
|
|
|
|
(defun erc-cmd-SOUND (line &optional force)
|
|
"Send a CTCP SOUND message to the default target.
|
|
If `erc-play-sound' is non-nil, play the sound as well.
|
|
|
|
/sound filename optional-message-text
|
|
|
|
LINE is the text entered, including the command."
|
|
(cond
|
|
((string-match "^\\s-*\\(\\S-+\\)\\(\\s-.*\\)?$" line)
|
|
(let ((file (match-string 1 line))
|
|
(msg (match-string 2 line))
|
|
(tgt (erc-default-target)))
|
|
(if (null msg)
|
|
(setq msg "")
|
|
;; remove the first white space
|
|
(setq msg (substring msg 1)))
|
|
(if tgt
|
|
(progn
|
|
(erc-send-ctcp-message tgt (format "SOUND %s %s" file msg) force)
|
|
(if erc-play-sound (erc-play-sound file)))
|
|
(erc-display-message nil 'error (current-buffer) 'no-target))
|
|
t))
|
|
(t nil)))
|
|
|
|
(defun erc-ctcp-query-SOUND (_proc nick login host _to msg)
|
|
"Display a CTCP SOUND message and play sound if `erc-play-sound' is non-nil."
|
|
(when (string-match "^SOUND\\s-+\\(\\S-+\\)\\(\\(\\s-+.*\\)\\|\\(\\s-*\\)\\)$" msg)
|
|
(let ((sound (match-string 1 msg))
|
|
(comment (match-string 2 msg)))
|
|
(when erc-play-sound (erc-play-sound sound))
|
|
(erc-display-message
|
|
nil 'notice nil
|
|
'CTCP-SOUND ?n nick ?u login ?h host ?s sound ?m comment)))
|
|
nil)
|
|
|
|
(defun erc-play-sound (file)
|
|
"Play a sound file located in one of the directories in `erc-sound-path'.
|
|
See also `play-sound-file'."
|
|
(let ((filepath (erc-find-file file erc-sound-path)))
|
|
(if (and (not filepath) erc-default-sound)
|
|
(setq filepath erc-default-sound))
|
|
(cond ((and filepath (file-exists-p filepath))
|
|
(play-sound-file filepath))
|
|
(t (beep)))
|
|
(erc-log (format "Playing sound file %S" filepath))))
|
|
|
|
(defun erc-toggle-sound (&optional arg)
|
|
"Toggle playing sounds on and off.
|
|
With positive argument, turns them on. With any other argument
|
|
turns sounds off."
|
|
(interactive "P")
|
|
(cond ((and (numberp arg) (> arg 0))
|
|
(setq erc-play-sound t))
|
|
(arg (setq erc-play-sound nil))
|
|
(t (setq erc-play-sound (not erc-play-sound))))
|
|
(message "ERC sound is %s" (if erc-play-sound "ON" "OFF")))
|
|
|
|
|
|
(provide 'erc-sound)
|
|
|
|
;;; erc-sound.el ends here
|
|
;;
|
|
;; Local Variables:
|
|
;; generated-autoload-file: "erc-loaddefs.el"
|
|
;; End:
|